//import processing.opengl.*;

int lati;
float dAng;
float [] cosArr,sinArr;

int numHex;
float globalR;
Hexagon [][] hexArr;
float dx,dy;

int rows,cols;
boolean up;

PImage originalImg,img;
int imgCropX,imgCropY;

void setup(){

  size(400,400,P3D);
  //noStroke();
  //smooth();
  colorMode(HSB,1);
  cursor(CROSS);

  //

  lati=6;
  dAng=radians(360/lati);

  cosArr=new float [lati];
  sinArr=new float [lati];

  for(int i=0;i<lati;i++){
    cosArr[i]=cos(dAng*i);
    sinArr[i]=sin(dAng*i);
  }

  //
  globalR=11;

  //
  generateHexagons();

  //Load Image
  originalImg=loadImage("http://de.posi.to/parsons/picz/img.jpg");
  //originalImg=loadImage("img.jpg");
  //Crop in relation ti stage width and height
  imgCropX=int((originalImg.width-width)*.5);
  imgCropY=int((originalImg.height-height)*.5);
  img=originalImg.get(imgCropX,imgCropY,width,height);

}

void draw(){

  background(90);

  for(int x=0;x<cols;x++){
    for(int y=0;y<rows;y++){
      hexArr[x][y].update();
    }
  }


}

class Hexagon{

  float cx,cy,x,y,cxNorm,cyNorm,r;

  float brightnessValue;

  Hexagon(float _cx,float _cy,float _r){

    cx=_cx;
    cy=_cy;
    r=_r;

  }

  void update(){

    cxNorm= cx/width;
    cxNorm=constrain(cxNorm,0.0,1.0);

    cyNorm= cy/height;
    cyNorm=constrain(cyNorm,0.0,1.0);

    brightnessValue=brightness(img.get(int(cxNorm*img.width),int(cyNorm*img.height)));

    //
    render();

  }


  void render(){

    //

    fill(brightnessValue);
    //stroke(1.0-brightnessValue);

    beginShape();

    for(int i=0;i<lati;i++){
      x=cx+cosArr[i]*r;
      y=cy+sinArr[i]*r;
      vertex(x,y);
    }

    endShape(CLOSE);

    //

  }

}

void keyPressed(){

  //println(keyCode);

  if(keyCode==521){

    //PLUS
    noLoop();

    //Update globalR
    globalR+=1;
    globalR=constrain(globalR,3,100);
    //println("GLOBAL R: "+globalR);

    ///Generate new hexagons
    generateHexagons();

    //Restore loop
    loop();

  }
  else if(keyCode==45){

    //MINUS

    //Stop loop
    noLoop();

    //Update globalR
    globalR-=1;
    globalR=constrain(globalR,3,100);
    //println("GLOBAL R: "+globalR);

    ///Generate new hexagons
    generateHexagons();

    //Restore loop
    loop();

  }
  else if(keyCode==38){

    //UP
    if(originalImg.height>height){
      imgCropY-=1;
      imgCropY=constrain(imgCropY,0,originalImg.height-height);
      img=originalImg.get(imgCropX,imgCropY,width,height);
    }

  }
  else if(keyCode==40){

    //DOWN
    if(originalImg.height>height){
      imgCropY+=1;
      imgCropY=constrain(imgCropY,0,originalImg.height-height);
      img=originalImg.get(imgCropX,imgCropY,width,height);
    }

  }
  else if(keyCode==39){

    //RIGHT
    if(originalImg.width>width){
      imgCropX+=1;
      imgCropX=constrain(imgCropX,0,originalImg.width-width);
      img=originalImg.get(imgCropX,imgCropY,width,height);
    }

  }
  else if(keyCode==37){

    //LEFT
    if(originalImg.width>width){
      imgCropX-=1;
      imgCropX=constrain(imgCropX,0,originalImg.width-width);
      img=originalImg.get(imgCropX,imgCropY,width,height);
    }

  }

  //println(keyCode);


}

void generateHexagons(){

  ///Generate new hexagons
  up=false;

  dy=(sqrt(3)*globalR);
  dx=(globalR/2)*3;

  cols=int(width/dx)+2;
  rows=int(height/dy)+3;

  //println(cols);

  hexArr=new Hexagon [cols][rows];

  for(int x=0;x<cols;x++){
    for(int y=0;y<rows;y++){
      if(up==false){
        hexArr[x][y]=new Hexagon(dx*x,dy*.5+dy*y,globalR);
      }
      else{
        hexArr[x][y]=new Hexagon(dx*x,-dy+dy*y,globalR);
      }

    }
    //Invert verse
    up=!up;
  }
  ///

}